home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / byte1286.arc / FALOUT.BAS < prev    next >
Encoding:
BASIC Source File  |  1986-10-29  |  2.0 KB  |  63 lines
  1. 10 REM                          LISTING 2
  2. 20 REM
  3. 30 REM FALOUT - A NUCLEAR FALLOUT CALC PROGRAM
  4. 40 REM (C) JOHN R. FANCHI, JULY 1985
  5. 50 REM MICROSOFT BASIC ON CP/M-80 OPERATING SYSTEM
  6. 60 REM CHR$(26) CLEARS SCREEN
  7. 70 PRINT CHR$(26)
  8. 80 PRINT " FALOUT - ESTIMATING THE DISTRIBUTION OF NUCLEAR FALLOUT"
  9. 90 PRINT
  10. 100 PRINT "(C) J.R. FANCHI, JULY 1985
  11. 110 PRINT: PRINT: PRINT 
  12. 120 PRINT "ESTIMATING RADIATION DOSAGE"
  13. 130 PRINT
  14. 140 INPUT "ENTER THE YIELD OF THE NUCLEAR BLAST IN MEGATONS: ", Y
  15. 150 PRINT
  16. 160 INPUT "ENTER YOUR DISTANCE FROM THE BLAST IN MILES: ", D
  17. 170 PRINT
  18. 180 REMS=250*1000*Y/(16*3.1416*D*D)
  19. 190 PRINT "ESTIMATED RADIATION DOSAGE IN REMS: ",REMS
  20. 200 PRINT
  21. 210 PRINT: PRINT: PRINT
  22. 220 PRINT "ESTIMATING FALLOUT DISTRIBUTION"
  23. 230 PRINT 
  24. 240 PRINT "THE DISTRIBUTION OF FALLOUT IS TREATED AS A RANDOM WALK PROCESS"
  25. 250 PRINT "SIMILAR TO BROWNIAN MOTION."
  26. 260 PRINT
  27. 270 INPUT "ENTER THE LINE-OF-SIGHT WIND SPEED (MPH): ",VPAR
  28. 280 VPAR=VPAR*24!
  29. 290 PRINT
  30. 300 INPUT "ENTER THE LINE-OF-SIGHT DISPERSION (SQ MILES/D): ",DPAR
  31. 310 PRINT
  32. 320 INPUT "ENTER THE TRANSVERSE WIND SPEED (MPH): ",VTRANS
  33. 330 VTRANS=VTRANS*24!
  34. 340 PRINT
  35. 350 INPUT "ENTER THE TRANSVERSE DISPERSION (SQ MILES/D): ",DTRANS
  36. 360 PRINT
  37. 370 REM
  38. 380 PRINT "RADIATION DOSAGE AT YOUR LOCATION AS A FUNCTION OF TIME"
  39. 390 PRINT "DAYS","REMS","NORM","HRS"
  40. 400 REM
  41. 410 ALPHA=D*D/(4*DPAR)
  42. 420 BETA=-2*D*VPAR/(4*DPAR)
  43. 430 GAMMA=VPAR*VPAR/(4*DPAR) + VTRANS*VTRANS/(4*DTRANS)
  44. 440 TFAC=SQR(1+4*ALPHA*GAMMA)
  45. 450 TYMMAX=(1+TFAC)/(2*GAMMA)
  46. 460 FACMAX=((D-VPAR*TYMMAX)^2)/(4*DPAR*TYMMAX)
  47. 470 FACMAX=FACMAX+VTRANS*VTRANS*TYMMAX/(4*DTRANS)
  48. 480 FOR I=1 TO 20 STEP 1
  49. 490 TYM=TYMMAX*(1-.02*(10-I))
  50. 500 FACPAR=0! : FACPER=0!
  51. 510 DISPAR=D-VPAR*TYM
  52. 520 DISPER=VTRANS*TYM
  53. 530 FACPAR=DISPAR*DISPAR/(4!*DPAR*TYM)
  54. 540 IF DTRANS<>0! THEN FACPER=DISPER*DISPER/(4!*DTRANS*TYM)
  55. 550 FACTOR=FACPAR+FACPER
  56. 560 COEF=TYMMAX/TYM
  57. 570 EFFREM=REMS*COEF*EXP(FACMAX-FACTOR)
  58. 580 NORM=EFFREM/REMS
  59. 590 TYMHRS=TYM*24
  60. 600 PRINT TYM,EFFREM,NORM,TYMHRS
  61. 610 NEXT I
  62. 620 END
  63.